Qt Reference Documentation

- Qt 4.8
- ALL VERSIONS

- A
- A
- A
- Print

# main.qml Example File

declarative/shadereffects/qml/shadereffects/main.qml

     /****************************************************************************
     **
     ** Copyright (C) 2015 The Qt Company Ltd.
     ** Contact: http://www.qt.io/licensing/
     **
     ** This file is part of the examples of the Qt Toolkit.
     **
     ** $QT_BEGIN_LICENSE:LGPL$
     ** Commercial License Usage
     ** Licensees holding valid commercial Qt licenses may use this file in
     ** accordance with the commercial license agreement provided with the
     ** Software or, alternatively, in accordance with the terms contained in
     ** a written agreement between you and The Qt Company. For licensing terms
     ** and conditions see http://www.qt.io/terms-conditions. For further
     ** information use the contact form at http://www.qt.io/contact-us.
     **
     ** GNU Lesser General Public License Usage
     ** Alternatively, this file may be used under the terms of the GNU Lesser
     ** General Public License version 2.1 or version 3 as published by the Free
     ** Software Foundation and appearing in the file LICENSE.LGPLv21 and
     ** LICENSE.LGPLv3 included in the packaging of this file. Please review the
     ** following information to ensure the GNU Lesser General Public License
     ** requirements will be met: https://www.gnu.org/licenses/lgpl.html and
     ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
     **
     ** As a special exception, The Qt Company gives you certain additional
     ** rights. These rights are described in The Qt Company LGPL Exception
     ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
     **
     ** GNU General Public License Usage
     ** Alternatively, this file may be used under the terms of the GNU
     ** General Public License version 3.0 as published by the Free Software
     ** Foundation and appearing in the file LICENSE.GPL included in the
     ** packaging of this file.  Please review the following information to
     ** ensure the GNU General Public License version 3.0 requirements will be
     ** met: http://www.gnu.org/copyleft/gpl.html.
     **
     ** $QT_END_LICENSE$
     **
     ****************************************************************************/

     import QtQuick 1.0
     import Qt.labs.shaders 1.0

     Item {
         id: main
         width: 360
         height: 640

         Rectangle {
             anchors.fill: parent
             color: "black"
         }

         Image {
             id: header
             source: "images/shader_effects.jpg"
         }

         ListModel {
             id: demoModel
             ListElement { name: "ImageMask" }
             ListElement { name: "RadialWave" }
             ListElement { name: "Water" }
             ListElement { name: "Grayscale" }
             ListElement { name: "DropShadow" }
             ListElement { name: "Curtain" }
         }

         Grid {
             id: menuGrid
             anchors.top: header.bottom
             anchors.bottom: toolbar.top
             width: parent.width
             columns: 2
             Repeater {
                 model: demoModel
                 Item {
                     width: main.width / 2
                     height: menuGrid.height / 3
                     clip: true
                     Image {
                         width: parent.width
                         height: width
                         source: "images/" + name + ".jpg"
                         opacity: mouseArea.pressed ? 0.6 : 1.0
                     }
                     MouseArea {
                         id: mouseArea
                         anchors.fill: parent
                         onClicked: {
                             demoLoader.source = name + ".qml"
                             main.state = "showDemo"
                         }
                     }
                 }
             }
         }

         Loader {
             anchors.fill: parent
             id: demoLoader
             visible: false
             Behavior on opacity {
                 NumberAnimation { duration: 300 }
             }
         }

         Image {
             id: toolbar
             source: "images/toolbar.png"
             width: parent.width
             anchors.bottom: parent.bottom
         }

         Rectangle {
             id: translucentToolbar
             color: "black"
             opacity: 0.3
             anchors.fill: toolbar
             visible: !toolbar.visible
         }

         Item {
             height: toolbar.height
             width: height
             anchors.bottom: parent.bottom

             Image {
                 source: "images/back.png"
                 anchors.centerIn: parent
             }

             MouseArea {
                 anchors.fill: parent
                 onClicked: {
                     if (main.state == "") Qt.quit(); else {
                         main.state = ""
                         demoLoader.source = ""
                     }
                 }
             }
         }

         states: State {
             name: "showDemo"
             PropertyChanges {
                 target: menuGrid
                 visible: false
             }
             PropertyChanges {
                 target: demoLoader
                 visible: true
             }
             PropertyChanges {
                 target: toolbar
                 visible: false
             }
         }
     }